/*
 * This file:
 *   http://anggtwu.net/MAXIMA/2025-1-MV-abril.mac.html
 *   http://anggtwu.net/MAXIMA/2025-1-MV-abril.mac
 *          (find-angg "MAXIMA/2025-1-MV-abril.mac")
 * Author: Eduardo Ochs <eduardoochs@gmail.com>
 *
 * (defun e () (interactive) (find-angg "MAXIMA/2025-1-MV-abril.mac"))
 * (defun l () (interactive) (find-angg "MAXIMA/2025-1-MV-abril.lisp"))
 * (find-angg ".maxima/maxima-init.mac" "align_eqs")
 * (c2m251dip 15 "MVDs-MVIs")
 * (c2m251dia    "MVDs-MVIs")
 *
 * «.align_eqs_1c»		(to "align_eqs_1c")
 * «.align_eqs_1c-tests»	(to "align_eqs_1c-tests")
 * «.applys»			(to "applys")
 * «.applys-tests»		(to "applys-tests")
*/


/* «align_eqs_1c»  (to ".align_eqs_1c")
 * (find-angg ".maxima/maxima-init.mac" "align_eqs")
*/
align_eqs_1c  (exprs) := apply('matrix, align_eqs_1c_0(exprs))$
align_eqs_1c_0(exprs) := append([["", exprs[1]]],
                                makelist(["=", exprs[i]], i,2,length(exprs)))$

/* «align_eqs_1c-tests»  (to ".align_eqs_1c-tests")
* (eepitch-maxima)
* (eepitch-kill)
* (eepitch-maxima)
load("2025-1-MV-abril.mac");
align_eqs_1c  ([1,2,3,4]);
align_eqs_1c_0([1,2,3,4]);

*/



/* (find-fline "~/MAXIMA/2025-1-MV-abril.lisp")
 * (find-fline "~/MAXIMA/dim-antideriv.lisp")
*/
load("2025-1-MV-abril.lisp");
load("dim-antideriv.lisp");

Integrate  (f,x,a,b) := Integrate_(f,x,x=a,x=b);
Integrate_I(f,x,a,b) := Integrate_(f,x);
At2(f,x,a,b) := matrix(["", "|", x=b],
                       [f,  "|",  ""],
                       ["", "|", x=a]);

At2(f,x,a,b) := antideriv(f, x, a, b);

texput(antideriv, antideriv_tex);
antideriv_tex(o) :=
  block([fx,x,a,b], [fx,x,a,b]:args(o),
        format("\\left.~a\\right|_{~a=~a}^{~a=~a}",
               tex1(fx), tex1(x),tex1(a), tex1(x),tex1(b)));

/*
* (eepitch-maxima)
* (eepitch-kill)
* (eepitch-maxima)
load("2025-1-MV-abril.mac");
Integrate_(f,x,a,b);
Integrate (f,x,a,b);
At2       (F,x,a,b);

*/


/* «applys»  (to ".applys")
*/
"_a_" (fs,x) := block([result:x],
  for kk : length(fs) thru 1 step -1 do result : fs[kk](result),
  result)$
infix("_a_",99,101);

/* «applys-tests»  (to ".applys-tests")
* (eepitch-maxima)
* (eepitch-kill)
* (eepitch-maxima)
load("2025-1-MV-abril.mac");
[f,g,h] _a_ (xx);

*/

gradef(f(x), fp(x));
gradef(g(x), gp(x));
gradef(h(x), hp(x));
gradef(k(x), kp(x));
texput(fp, "f'");
texput(gp, "g'");
texput(hp, "h'");
texput(kp, "k'");

Integrate3  (fg,hk,vv) := Integrate  (diff(fg _a_ vv, vv), vv, hk _a_ a, hk _a_ b);
Diff3       (fg,hk,vv) := At2        (     fg _a_ vv,      vv, hk _a_ a, hk _a_ b);
Diff2       (fghk, vv) :=                              (fghk _a_ b) - (fghk _a_ a);

Integrate3_I(fg,hk,vv) := Integrate_I(diff(fg _a_ vv, vv), vv, hk _a_ a, hk _a_ b);
Diff3_I     (fg,hk,vv) :=                  fg _a_ vv;


/*
* (eepitch-maxima)
* (eepitch-kill)
* (eepitch-maxima)
load("2025-1-MV-abril.mac");
Integrate3_I([f,g],[h,k],x);
Diff3_I([f,g],[h,k],x);

*/




MVDs_fgh  : [Integrate3([f,g,h],[],x),
             Integrate3([f,g], [h],u),
             Integrate3([f], [g,h],v),
             Diff3     ([f], [g,h],v),
             Diff3     ([f,g], [h],u),
             Diff3     ([f,g,h],[],x)];

MVIs_fgh  : [Integrate3_I([f,g,h],[],x),
             Integrate3_I([f,g], [h],u),
             Integrate3_I([f], [g,h],v),
             Diff3_I     ([f], [g,h],v),
             Diff3_I     ([f,g], [h],u),
             Diff3_I     ([f,g,h],[],x)];

MVDs_fghk : [Integrate3([f,g,h,k],[],x),
             Integrate3([f,g,h], [k],u),
             Integrate3([f,g], [h,k],v),
             Integrate3([f], [g,h,k],w),
             Diff3     ([f], [g,h,k],w),
             Diff3     ([f,g], [h,k],v),
             Diff3     ([f,g,h], [k],u),
             Diff3     ([f,g,h,k],[],x)];

MVIs_fghk : [Integrate3_I([f,g,h,k],[],x),
             Integrate3_I([f,g,h], [k],u),
             Integrate3_I([f,g], [h,k],v),
             Integrate3_I([f], [g,h,k],w),
             Diff3_I     ([f], [g,h,k],w),
             Diff3_I     ([f,g], [h,k],v),
             Diff3_I     ([f,g,h], [k],u),
             Diff3_I     ([f,g,h,k],[],x)];


/*
(find-angg ".maxima/maxima-init.mac" "align_eqs")

* (eepitch-maxima)
* (eepitch-kill)
* (eepitch-maxima)
load("2025-1-MV-abril.mac");
align_eqs_1c(MVDs_fgh);
align_eqs_1c(MVIs_fgh);
align_eqs_1c(MVDs_fghk);
align_eqs_1c(MVIs_fghk);

*/